Merge pull request #208 from dagar/master

initial cmake support

.gitignore

@@ -20,6 +20,8 @@ pyston_release
 pyston_grwl
 pyston_grwl_dbg
 pyston_nosync
+/gc
+/analysis
 
 *.cache
 tests/t.py

.gitmodules

+[submodule "libunwind"]
+	path = libunwind
+	url = git://git.sv.gnu.org/libunwind.git
+[submodule "libpypa"]
+	path = libpypa
+	url = https://github.com/vinzenz/libpypa.git

CMakeLists.txt

+cmake_minimum_required(VERSION 2.8)
+project(pyston)
+
+include(ExternalProject)
+
+set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
+set(DEPS_DIR $ENV{HOME}/pyston_deps)
+
+# set build type to release by default
+set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "" FORCE)
+if(NOT CMAKE_BUILD_TYPE)
+  set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release." FORCE)
+endif()
+if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "Release" AND NOT ${CMAKE_BUILD_TYPE} STREQUAL "Debug")
+  message(FATAL_ERROR "CMAKE_BUILD_TYPE must be set to Release or Debug")
+endif()
+
+option(ENABLE_GIL "threading use GIL" ON)
+option(ENABLE_GRWL "threading use GRWL" OFF)
+option(ENABLE_INTEL_JIT_EVENTS "LLVM support for Intel JIT Events API" OFF)
+option(ENABLE_LLVM_DEBUG "LLVM debug symbols" OFF)
+option(ENABLE_VALGRIND "pyston valgrind support" OFF)
+
+# initial clang flags (set here so they're used when building llvm)
+set(CLANG_FLAGS "-Qunused-arguments -fcolor-diagnostics" CACHE STRING "Clang specific C and CXX flags")
+if("${CMAKE_C_COMPILER_ID}" STREQUAL "Clang")
+  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${CLANG_FLAGS}")
+endif()
+if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
+  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CLANG_FLAGS}")
+endif()
+
+# llvm disable debug info unless ENABLE_LLVM_DEBUG is ON
+if(${CMAKE_BUILD_TYPE} STREQUAL "Debug" AND NOT ENABLE_LLVM_DEBUG)
+  set(CMAKE_CXX_FLAGS_DEBUG "-g0" CACHE STRING "" FORCE)
+endif()
+
+execute_process(COMMAND cat llvm_revision.txt WORKING_DIRECTORY ${CMAKE_SOURCE_DIR} OUTPUT_VARIABLE LLVMREV OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+# llvm and clang patches
+add_custom_target(llvm_gotorev python ${CMAKE_SOURCE_DIR}/tools/git_svn_gotorev.py ${DEPS_DIR}/llvm-trunk ${LLVMREV} llvm_patches WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+add_custom_target(clang_gotorev python ${CMAKE_SOURCE_DIR}/tools/git_svn_gotorev.py ${DEPS_DIR}/llvm-trunk/tools/clang ${LLVMREV} clang_patches WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+add_custom_target(llvm_up DEPENDS llvm_gotorev clang_gotorev)
+
+# llvm
+set(LLVM_TARGETS_TO_BUILD "host" CACHE STRING "LLVM targets")
+#set(LLVM_EXTERNAL_CLANG_SOURCE_DIR "${CMAKE_SOURCE_DIR}/clang" CACHE String "Clang directory")
+#add_subdirectory(llvm EXCLUDE_FROM_ALL)
+if(ENABLE_INTEL_JIT_EVENTS)
+  set(LLVM_USE_INTEL_JITEVENTS "ON" CACHE STRING "Enable building support for the Intel JIT Events API")
+  set(INTEL_JIT_EVENTS_LIB "inteljitevents")
+  add_definitions(-DENABLE_INTEL_JIT_EVENTS=1)
+endif()
+add_subdirectory(${DEPS_DIR}/llvm-trunk ${CMAKE_BINARY_DIR}/llvm)
+set(CMAKE_MODULE_PATH "${CMAKE_BINARY_DIR}/llvm/share/llvm/cmake/")
+include(LLVMConfig)
+llvm_map_components_to_libnames(LLVM_LIBS core mcjit native bitreader ipo irreader debuginfo instrumentation ${INTEL_JIT_EVENTS_LIB})
+
+# libunwind
+if("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
+  set(LIBUNWIND_FLAGS "-g -O0")
+  set(LIBUNWIND_DEBUG "--enable-debug")
+  set(LIBUNWIND_DEBUG_FRAME "--enable-debug-frame")
+endif()
+ExternalProject_Add(libunwind
+                    PREFIX libunwind
+                    SOURCE_DIR ${CMAKE_SOURCE_DIR}/libunwind
+                    UPDATE_COMMAND autoreconf -i
+                    CONFIGURE_COMMAND ${CMAKE_SOURCE_DIR}/libunwind/configure CC=${CMAKE_C_COMPILER} CXX=${CMAKE_CXX_COMPILER} CFLAGS=${LIBUNWIND_FLAGS} CXXFLAGS=${LIBUNWIND_FLAGS} --prefix=${CMAKE_BINARY_DIR}/libunwind --enable-shared=0 ${LIBUNWIND_DEBUG} ${LIBUNWIND_DEBUG_FRAME}
+                    LOG_UPDATE ON
+                    LOG_CONFIGURE ON
+                    LOG_BUILD ON
+                    LOG_INSTALL ON)
+
+# libpypa
+add_subdirectory(libpypa)
+
+# valgrind
+if(ENABLE_VALGRIND)
+  find_package(Valgrind REQUIRED)
+  include_directories(${VALGRIND_INCLUDE_DIR})
+  message(STATUS "Including valgrind ${VALGRIND_INCLUDE_DIR}")
+else()
+  add_definitions(-DNVALGRIND)
+endif()
+
+if(ENABLE_GRWL)
+  add_definitions(-DTHREADING_USE_GIL=0 -DTHREADING_USE_GRWL=1)
+else()
+  add_definitions(-DTHREADING_USE_GIL=1 -DTHREADING_USE_GRWL=0)
+endif()
+
+set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Werror -Wreturn-type -Wno-sign-compare -Wno-unused -Wno-sign-compare -Wno-unused-parameter -fno-omit-frame-pointer")
+set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_C_FLAGS} -std=c++11 -fno-rtti -fexceptions -fvisibility-inlines-hidden -ffunction-sections -fdata-sections -Woverloaded-virtual -Wno-invalid-offsetof -Wcast-qual -Wno-sign-conversion -Wnon-virtual-dtor -Winit-self -Wmissing-include-dirs -Wstrict-overflow=5 -Wpointer-arith -Wtype-limits -Wwrite-strings -Wempty-body -Waggregate-return -Wmissing-field-initializers -Wredundant-decls -Winline -Wint-to-pointer-cast -Wlong-long -Wvla")
+
+set(CLANG_FLAGS "${CLANG_FLAGS} -Wimplicit-int -Wstrict-prototypes -Wold-style-definition -Wnested-externs -Wpointer-to-int-cast -Wno-mismatched-tags -Wno-extern-c-compat")
+if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
+  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CLANG_FLAGS}")
+endif()
+
+if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
+  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-long-long -Wno-aggregate-return -Wno-inline -Wno-redundant-decls -Wno-strict-overflow")
+endif()
+
+add_definitions(${LLVM_DEFINITIONS})
+add_definitions(-DDEFAULT_PYTHON_MAJOR_VERSION=2 -DDEFAULT_PYTHON_MINOR_VERSION=7 -DDEFAULT_PYTHON_MICRO_VERSION=6) # Python 2.7.6
+add_definitions(-DLLVMREV=${LLVMREV})
+
+include_directories(${LLVM_INCLUDE_DIRS})
+include_directories(include)
+
+find_package(LibLZMA REQUIRED)
+link_directories(${CMAKE_BINARY_DIR}/libunwind/lib)
+link_directories(${LLVM_LIBRARY_DIRS})
+
+add_subdirectory(lib_python)
+add_subdirectory(src)
+add_subdirectory(test/test_extension)
+add_subdirectory(test/unittests)
+add_subdirectory(tools)
+
+add_executable(pyston $<TARGET_OBJECTS:PYSTON_MAIN_OBJECT> $<TARGET_OBJECTS:PYSTON_OBJECTS> $<TARGET_OBJECTS:FROM_CPYTHON_OBJECTS>)
+target_link_libraries(pyston stdlib pthread m readline gmp unwind pypa double-conversion ${LLVM_LIBS} ${LIBLZMA_LIBRARIES})
+
+# copy the python standard library (lib_python/2.7) and src/codegen/parse_ast.py to the build directory
+add_custom_command(TARGET pyston POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_SOURCE_DIR}/lib_python/2.7 ${CMAKE_BINARY_DIR}/lib_python/2.7)
+add_custom_command(TARGET pyston POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_SOURCE_DIR}/src/codegen/parse_ast.py ${CMAKE_BINARY_DIR}/src/codegen/parse_ast.py)
+
+add_custom_target(astcompare COMMAND ${CMAKE_SOURCE_DIR}/tools/astprint_test.sh
+                  DEPENDS astprint
+                  COMMENT "Running libpypa vs CPython AST result comparison test")
+
+# test
+enable_testing()
+add_test(NAME lint COMMAND python ${CMAKE_SOURCE_DIR}/tools/lint.py WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src)
+add_test(NAME check-format COMMAND ${CMAKE_SOURCE_DIR}/tools/check_format.sh ${LLVM_TOOLS_BINARY_DIR}/clang-format WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src)
+add_test(NAME gc_unittest COMMAND gc_unittest)
+add_test(NAME analysis_unittest COMMAND analysis_unittest)
+add_test(NAME pyston_defaults COMMAND python ${CMAKE_SOURCE_DIR}/tools/tester.py -R ./pyston -j4 -k ${CMAKE_SOURCE_DIR}/test/tests)
+add_test(NAME pyston_disable_interpreter COMMAND python ${CMAKE_SOURCE_DIR}/tools/tester.py -R ./pyston -j4 -k -a -n -k ${CMAKE_SOURCE_DIR}/test/tests)
+add_test(NAME pyston_max_compilation_tier COMMAND python ${CMAKE_SOURCE_DIR}/tools/tester.py -R ./pyston -j4 -a -O -k ${CMAKE_SOURCE_DIR}/test/tests)
+
+# format
+file(GLOB_RECURSE FORMAT_FILES ${CMAKE_SOURCE_DIR}/src/*.h ${CMAKE_SOURCE_DIR}/src/*.cpp)
+add_custom_target(format ${LLVM_TOOLS_BINARY_DIR}/clang-format -style=file -i ${FORMAT_FILES} DEPENDS clang-format WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src)
+add_custom_target(check-format ${CMAKE_SOURCE_DIR}/tools/check_format.sh ${LLVM_TOOLS_BINARY_DIR}/clang-format DEPENDS clang-format WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src)
+
+# lint
+add_custom_target(lint python ${CMAKE_SOURCE_DIR}/tools/lint.py WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src)
+
+# check
+add_custom_target(check-pyston COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure DEPENDS pyston clang-format ext_cpython ext_pyston unittests) 
+
+# {run,dbg,perf,memcheck,memleaks,cachegrind}_TESTNAME
+file(GLOB RUNTARGETS ${CMAKE_SOURCE_DIR}/test/tests/*.py ${CMAKE_SOURCE_DIR}/microbenchmarks/*.py ${CMAKE_SOURCE_DIR}/minibenchmarks/*.py)
+foreach(RUNTARGET ${RUNTARGETS})
+  get_filename_component(BASEFILENAME ${RUNTARGET} NAME_WE)
+  add_custom_target(run_${BASEFILENAME} ./pyston -q ${RUNTARGET} DEPENDS pyston)
+  add_custom_target(dbg_${BASEFILENAME} gdb --ex "set confirm off" --ex "handle SIGUSR2 pass nostop noprint" --ex run --ex "bt 20" --args ./pyston -q ${RUNTARGET} DEPENDS pyston)
+  add_custom_target(perf_${BASEFILENAME} perf record -g -- ./pyston -q -p ${RUNTARGET}
+                    COMMAND perf report -v -n -g flat,1000 | bash ${CMAKE_SOURCE_DIR}/tools/cumulate.sh | less -S)
+
+  if(ENABLE_VALGRIND)
+    add_custom_target(memcheck_${BASEFILENAME} valgrind --tool=memcheck --leak-check=no --db-attach=yes ./pyston ${RUNTARGET} DEPENDS pyston)
+    add_custom_target(memleaks_${BASEFILENAME} valgrind --tool=memcheck --leak-check=full --leak-resolution=low --show-reachable=yes ./pyston ${RUNTARGET} DEPENDS pyston)
+    add_custom_target(cachegrind_${BASEFILENAME} valgrind --tool=cachegrind ./pyston ${RUNTARGET} DEPENDS pyston)
+  endif()
+endforeach()

src/Makefile → Makefile

@@ -4,7 +4,7 @@
 USE_TEST_LLVM := 0
 DEPS_DIR := $(HOME)/pyston_deps
 
-LLVM_REVISION_FILE := ../llvm_revision.txt
+LLVM_REVISION_FILE := llvm_revision.txt
 LLVM_REVISION := $(shell cat $(LLVM_REVISION_FILE))
 
 USE_CLANG  := 1
@@ -45,8 +45,9 @@ FORCE_TRUNK_BINARIES := 0
 -include Makefile.local
 
 
-TOOLS_DIR := ../tools
-TESTS_DIR := ../test/tests
+TOOLS_DIR := ./tools
+TEST_DIR := ./test
+TESTS_DIR := ./test/tests
 
 GPP := $(GCC_DIR)/bin/g++
 GCC := $(GCC_DIR)/bin/gcc
@@ -128,7 +129,7 @@ LLVM_PROFILE_LIB_DEPS := $(wildcard $(LLVM_BUILD)/Release+Profile/lib/*)
 CLANG_EXE := $(LLVM_BIN)/clang
 CLANGPP_EXE := $(LLVM_BIN)/clang++
 
-COMMON_CFLAGS := -g -Werror -Wreturn-type -Wall -Wno-sign-compare -Wno-unused -I. -I../include -fno-omit-frame-pointer
+COMMON_CFLAGS := -g -Werror -Wreturn-type -Wall -Wno-sign-compare -Wno-unused -Isrc -I./include -fno-omit-frame-pointer
 COMMON_CFLAGS += -Wextra -Wno-sign-compare
 COMMON_CFLAGS += -Wno-unused-parameter # should use the "unused" attribute
 COMMON_CXXFLAGS := $(COMMON_CFLAGS)
@@ -151,7 +152,7 @@ COMMON_CXXFLAGS += -DGITREV=$(shell git rev-parse HEAD | head -c 12) -DLLVMREV=$
 COMMON_CXXFLAGS += -DDEFAULT_PYTHON_MAJOR_VERSION=$(PYTHON_MAJOR_VERSION) -DDEFAULT_PYTHON_MINOR_VERSION=$(PYTHON_MINOR_VERSION) -DDEFAULT_PYTHON_MICRO_VERSION=$(PYTHON_MICRO_VERSION)
 
 # Use our "custom linker" that calls gold if available
-COMMON_LDFLAGS := -B../tools/build_system -L/usr/local/lib -lpthread -lm -lunwind -llzma -L$(DEPS_DIR)/gcc-4.8.2-install/lib64 -lreadline -lgmp
+COMMON_LDFLAGS := -B$(TOOLS_DIR)/build_system -L/usr/local/lib -lpthread -lm -lunwind -llzma -L$(DEPS_DIR)/gcc-4.8.2-install/lib64 -lreadline -lgmp
 COMMON_LDFLAGS += $(DEPS_DIR)/pypa-install/lib/libpypa.a
 
 # Conditionally add libtinfo if available - otherwise nothing will be added
@@ -264,15 +265,15 @@ CLANG_CXX := $(CXX_ENV) $(CLANG_CXX)
 # Not sure if ccache_basedir actually helps at all (I think the generated files make them different?)
 LLVM_BUILD_ENV += CCACHE_DIR=$(HOME)/.ccache_llvm CCACHE_BASEDIR=$(LLVM_SRC)
 
-BASE_SRCS := $(wildcard codegen/*.cpp) $(wildcard asm_writing/*.cpp) $(wildcard codegen/irgen/*.cpp) $(wildcard codegen/opt/*.cpp) $(wildcard analysis/*.cpp) $(wildcard core/*.cpp) codegen/profiling/profiling.cpp codegen/profiling/dumprof.cpp $(wildcard runtime/*.cpp) $(wildcard runtime/builtin_modules/*.cpp) $(wildcard gc/*.cpp) $(wildcard capi/*.cpp)
-MAIN_SRCS := $(BASE_SRCS) jit.cpp
-STDLIB_SRCS := $(wildcard runtime/inline/*.cpp)
+BASE_SRCS := $(wildcard src/codegen/*.cpp) $(wildcard src/asm_writing/*.cpp) $(wildcard src/codegen/irgen/*.cpp) $(wildcard src/codegen/opt/*.cpp) $(wildcard src/analysis/*.cpp) $(wildcard src/core/*.cpp) src/codegen/profiling/profiling.cpp src/codegen/profiling/dumprof.cpp $(wildcard src/runtime/*.cpp) $(wildcard src/runtime/builtin_modules/*.cpp) $(wildcard src/gc/*.cpp) $(wildcard src/capi/*.cpp)
+MAIN_SRCS := $(BASE_SRCS) src/jit.cpp
+STDLIB_SRCS := $(wildcard src/runtime/inline/*.cpp)
 SRCS := $(MAIN_SRCS) $(STDLIB_SRCS)
 STDLIB_OBJS := stdlib.bc.o stdlib.stripped.bc.o
 STDLIB_RELEASE_OBJS := stdlib.release.bc.o
 
 STDMODULE_SRCS := errnomodule.c shamodule.c sha256module.c sha512module.c _math.c mathmodule.c md5.c md5module.c _randommodule.c _sre.c operator.c binascii.c $(EXTRA_STDMODULE_SRCS)
-FROM_CPYTHON_SRCS := $(addprefix ../lib_python/2.7_Modules/,$(STDMODULE_SRCS)) $(wildcard capi/*.c)
+FROM_CPYTHON_SRCS := $(addprefix lib_python/2.7_Modules/,$(STDMODULE_SRCS)) $(wildcard src/capi/*.c)
 
 # The stdlib objects have slightly longer dependency chains,
 # so put them first in the list:
@@ -281,10 +282,10 @@ ASTPRINT_OBJS := $(STDLIB_OBJS) $(BASE_SRCS:.cpp=.o) $(FROM_CPYTHON_SRCS:.c=.o)
 PROFILE_OBJS := $(STDLIB_RELEASE_OBJS) $(MAIN_SRCS:.cpp=.prof.o) $(STDLIB_SRCS:.cpp=.release.o) $(FROM_CPYTHON_SRCS:.c=.release.o)
 OPT_OBJS := $(STDLIB_RELEASE_OBJS) $(SRCS:.cpp=.release.o) $(FROM_CPYTHON_SRCS:.c=.release.o)
 
-OPTIONAL_SRCS := codegen/profiling/oprofile.cpp codegen/profiling/pprof.cpp
+OPTIONAL_SRCS := src/codegen/profiling/oprofile.cpp src/codegen/profiling/pprof.cpp
 TOOL_SRCS := $(wildcard $(TOOLS_DIR)/*.cpp)
 
-UNITTEST_DIR := ../test/unittests
+UNITTEST_DIR := $(TEST_DIR)/unittests
 UNITTEST_SRCS := $(wildcard $(UNITTEST_DIR)/*.cpp)
 
 NONSTDLIB_SRCS := $(MAIN_SRCS) $(OPTIONAL_SRCS) $(TOOL_SRCS) $(UNITTEST_SRCS)
@@ -300,23 +301,23 @@ NONSTDLIB_SRCS := $(MAIN_SRCS) $(OPTIONAL_SRCS) $(TOOL_SRCS) $(UNITTEST_SRCS)
 # all: pyston_dbg pyston_release pyston_oprof pyston_prof $(OPTIONAL_SRCS:.cpp=.o) ext_python ext_pyston
 all: pyston_dbg pyston_release pyston_prof ext_python ext_pyston unittests
 
-ALL_HEADERS := $(wildcard */*.h) $(wildcard */*/*.h) $(wildcard ../include/*.h)
+ALL_HEADERS := $(wildcard src/*/*.h) $(wildcard src/*/*/*.h) $(wildcard ./include/*.h)
 tags: $(SRCS) $(OPTIONAL_SRCS) $(ALL_HEADERS)
 	$(ECHO) Calculating tags...
 	$(VERB) ctags $^
 
-NON_ENTRY_OBJS := $(filter-out jit.o,$(OBJS))
+NON_ENTRY_OBJS := $(filter-out src/jit.o,$(OBJS))
 
 define add_unittest
 $(eval \
-$(UNITTEST_DIR)/$1: $(GTEST_DIR)/src/gtest-all.o $(NON_ENTRY_OBJS) $(BUILD_SYSTEM_DEPS) $(UNITTEST_DIR)/$1.o
+$1: $(GTEST_DIR)/src/gtest-all.o $(NON_ENTRY_OBJS) $(BUILD_SYSTEM_DEPS) $(UNITTEST_DIR)/$1.o
 	$(ECHO) Linking $$@
 	$(VERB) $(CXX) $(NON_ENTRY_OBJS) $(GTEST_DIR)/src/gtest-all.o $(GTEST_DIR)/src/gtest_main.o $(UNITTEST_DIR)/$1.o $(LDFLAGS) -o $$@
-dbg_$1_unittests: $(UNITTEST_DIR)/$1
-	zsh -c 'ulimit -v $(MAX_MEM_KB); ulimit -d $(MAX_MEM_KB); time $(GDB) $(GDB_CMDS) --args ./$(UNITTEST_DIR)/$1 --gtest_break_on_failure $(ARGS)'
-unittests:: $(UNITTEST_DIR)/$1
-run_$1_unittests: $(UNITTEST_DIR)/$1
-	zsh -c 'ulimit -v $(MAX_MEM_KB); ulimit -d $(MAX_MEM_KB); time ./$(UNITTEST_DIR)/$1 $(ARGS)'
+dbg_$1_unittests: $1
+	zsh -c 'ulimit -v $(MAX_MEM_KB); ulimit -d $(MAX_MEM_KB); time $(GDB) $(GDB_CMDS) --args ./$1 --gtest_break_on_failure $(ARGS)'
+unittests:: $1
+run_$1_unittests: $1
+	zsh -c 'ulimit -v $(MAX_MEM_KB); ulimit -d $(MAX_MEM_KB); time ./$1 $(ARGS)'
 run_unittests:: run_$1_unittests
 )
 endef
@@ -338,10 +339,10 @@ endef
 
 .PHONY: format check_format
 format:
-	find \( -name '*.cpp' -o -name '*.h' \) -print0 | xargs -0 $(LLVM_BIN)/clang-format -style=file -i
+	cd src && find \( -name '*.cpp' -o -name '*.h' \) -print0 | xargs -0 $(LLVM_BIN)/clang-format -style=file -i
 check_format:
 	$(ECHO) checking formatting...
-	$(VERB) $(TOOLS_DIR)/check_format.sh $(LLVM_BIN)/clang-format
+	$(VERB) cd src && ../tools/check_format.sh $(LLVM_BIN)/clang-format
 
 .PHONY: analyze
 analyze:
@@ -353,9 +354,9 @@ analyze:
 .PHONY: lint cpplint
 lint:
 	$(ECHO) linting...
-	$(VERB) python ../tools/lint.py
+	$(VERB) cd src && python ../tools/lint.py
 cpplint:
-	$(VERB) python ../tools/cpplint.py --filter=-whitespace,-build/header_guard,-build/include_order,-readability/todo $(SRCS)
+	$(VERB) cd src && python $(TOOLS_DIR)/cpplint.py --filter=-whitespace,-build/header_guard,-build/include_order,-readability/todo $(SRCS)
 
 .PHONY: check quick_check
 check:
@@ -553,11 +554,11 @@ llvm/profile/%: $(LLVM_SRC)/_patched $(LLVM_CONFIGURATION)
 	$(VERB) if [ ! -f $(patsubst llvm/profile/%,$(LLVM_BUILD)/%/Makefile,$@) ]; then cp $(patsubst llvm/profile/%,$(LLVM_SRC)/%/Makefile,$@) $(patsubst llvm/profile/%,$(LLVM_BUILD)/%/,$@); fi
 	$(LLVM_BUILD_ENV) $(MAKE) -C $(patsubst llvm/profile/%,$(LLVM_BUILD)/%,$@) $(LLVM_BUILD_VARS) CXXFLAGS="-fno-omit-frame-pointer -fno-function-sections" ENABLE_PROFILING=1 ENABLE_OPTIMIZED=1 DISABLE_ASSERTIONS=1 $(LLVM_MAKE_ARGS)
 
-$(LLVM_SRC)/_patched: $(wildcard ../llvm_patches/*) $(wildcard ../clang_patches/*) $(LLVM_REVISION_FILE)
+$(LLVM_SRC)/_patched: $(wildcard ./llvm_patches/*) $(wildcard ./clang_patches/*) $(LLVM_REVISION_FILE)
 	$(MAKE) llvm_up
 llvm_up:
-	python $(TOOLS_DIR)/git_svn_gotorev.py $(LLVM_SRC) $(LLVM_REVISION) ../llvm_patches
-	python $(TOOLS_DIR)/git_svn_gotorev.py $(LLVM_SRC)/tools/clang $(LLVM_REVISION) ../clang_patches
+	python $(TOOLS_DIR)/git_svn_gotorev.py $(LLVM_SRC) $(LLVM_REVISION) ./llvm_patches
+	python $(TOOLS_DIR)/git_svn_gotorev.py $(LLVM_SRC)/tools/clang $(LLVM_REVISION) ./clang_patches
 	$(MAKE) $(LLVM_CONFIGURATION)
 	touch $(LLVM_SRC)/_patched
 
@@ -602,7 +603,7 @@ astcompare: astprint
 ## END OF TOOLS
 
 
-CODEGEN_SRCS := $(wildcard codegen/*.cpp) $(wildcard codegen/*/*.cpp)
+CODEGEN_SRCS := $(wildcard src/codegen/*.cpp) $(wildcard src/codegen/*/*.cpp)
 
 # args: suffix (ex: ".release"), CXXFLAGS
 define make_compile_config
@@ -617,8 +618,8 @@ $$(SRCS:.cpp=$1.o.bc): CXXFLAGS:=$2
 	$$(ECHO) Compiling $$@
 	$$(VERB) rm -f $$@-*
 	$$(VERB) $$(CLANGPP_EXE) $$(CXXFLAGS) -MMD -MP -MF $$<.d -x c++-header $$< -o $$@
-$$(CODEGEN_SRCS:.cpp=$1.o): CXXFLAGS += -include codegen/irgen$1.h
-$$(CODEGEN_SRCS:.cpp=$1.o): codegen/irgen$1.h.pch
+$$(CODEGEN_SRCS:.cpp=$1.o): CXXFLAGS += -include src/codegen/irgen$1.h
+$$(CODEGEN_SRCS:.cpp=$1.o): src/codegen/irgen$1.h.pch
 
 $$(NONSTDLIB_SRCS:.cpp=$1.o): %$1.o: %.cpp $$(BUILD_SYSTEM_DEPS)
 	$$(ECHO) Compiling $$@
@@ -732,11 +733,11 @@ pyston_profile: $(PROFILE_OBJS) $(LLVM_PROFILE_DEPS)
 	$(VERB) $(CXX) $(PROFILE_OBJS) $(LDFLAGS_PROFILE) -o $@
 
 
--include $(wildcard *.d) $(wildcard */*.d) $(wildcard */*/*.d) $(wildcard $(UNITTEST_DIR)/*.d) $(wildcard ../lib_python/2.7_Modules/*.d)
+-include $(wildcard *.d) $(wildcard */*.d) $(wildcard */*/*.d) $(wildcard $(UNITTEST_DIR)/*.d) $(wildcard ./lib_python/2.7_Modules/*.d)
 
 .PHONY: clean
 clean:
-	@ find . $(TOOLS_DIR) ../test ../lib_python/2.7_Modules \( -name '*.o' -o -name '*.d' -o -name '*.py_cache' -o -name '*.bc' -o -name '*.o.ll' -o -name '*.pub.ll' -o -name '*.cache' -o -name 'stdlib*.ll' -o -name '*.pyc' -o -name '*.so' -o -name '*.a' -o -name '*.expected_cache' -o -name '*.pch' \) -print -delete
+	@ find . $(TOOLS_DIR) $(TEST_DIR) ./lib_python/2.7_Modules \( -name '*.o' -o -name '*.d' -o -name '*.py_cache' -o -name '*.bc' -o -name '*.o.ll' -o -name '*.pub.ll' -o -name '*.cache' -o -name 'stdlib*.ll' -o -name '*.pyc' -o -name '*.so' -o -name '*.a' -o -name '*.expected_cache' -o -name '*.pch' \) -print -delete
 	@ find \( -name 'pyston*' -executable -type f \) -print -delete
 	@ find $(TOOLS_DIR) -maxdepth 0 -executable -type f -print -delete
 	@ rm -rf oprofile_data
@@ -745,10 +746,10 @@ clean:
 # ex instead of saying "make tests/run_1", I can just write "make run_1"
 define make_search
 $(eval \
-$1: ../test/tests/$1 ;
-$1: ../microbenchmarks/$1 ;
-$1: ../minibenchmarks/$1 ;
-$1: ../benchmarks/$1 ;
+$1: $(TEST_DIR)/tests/$1 ;
+$1: ./microbenchmarks/$1 ;
+$1: ./minibenchmarks/$1 ;
+$1: ./benchmarks/$1 ;
 $(patsubst %, $$1: %/$$1 ;,$(EXTRA_SEARCH_DIRS))
 )
 endef
@@ -759,10 +760,10 @@ define make_target
 $(eval \
 .PHONY: test$1 check$1
 check$1 test$1: pyston$1 ext_pyston
-	python ../tools/tester.py -R pyston$1 -j$(TEST_THREADS) -k $(TESTS_DIR) $(ARGS)
-	python ../tools/tester.py -a -x -R pyston$1 -j$(TEST_THREADS) -k $(TESTS_DIR) $(ARGS)
-	python ../tools/tester.py -R pyston$1 -j$(TEST_THREADS) -a -n -k $(TESTS_DIR) $(ARGS)
-	python ../tools/tester.py -R pyston$1 -j$(TEST_THREADS) -a -O -k $(TESTS_DIR) $(ARGS)
+	python $(TOOLS_DIR)/tester.py -R pyston$1 -j$(TEST_THREADS) -k $(TESTS_DIR) $(ARGS)
+	python $(TOOLS_DIR)/tester.py -a -x -R pyston$1 -j$(TEST_THREADS) -k $(TESTS_DIR) $(ARGS)
+	python $(TOOLS_DIR)/tester.py -R pyston$1 -j$(TEST_THREADS) -a -n -k $(TESTS_DIR) $(ARGS)
+	python $(TOOLS_DIR)/tester.py -R pyston$1 -j$(TEST_THREADS) -a -O -k $(TESTS_DIR) $(ARGS)
 
 .PHONY: run$1 dbg$1
 run$1: pyston$1 $$(RUN_DEPS)
@@ -896,36 +897,36 @@ wdbg_%:
 
 .PHONY: test_asm test_cpp_asm
 test_asm:
-	$(CLANGPP_EXE) ../test/test.s -c -o test
+	$(CLANGPP_EXE) $(TEST_DIR)/test.s -c -o test
 	objdump -d test | less
 	@ rm test
 test_cpp_asm:
-	$(CLANGPP_EXE) ../test/test.cpp -o test -c -O3 -std=c++11
+	$(CLANGPP_EXE) $(TEST_DIR)/test.cpp -o test -c -O3 -std=c++11
 	# $(GPP) tests/test.cpp -o test -c -O3
 	objdump -d test | less
 	rm test
 test_cpp_dwarf:
-	$(CLANGPP_EXE) ../test/test.cpp -o test -c -O3 -std=c++11 -g
+	$(CLANGPP_EXE) $(TEST_DIR)/test.cpp -o test -c -O3 -std=c++11 -g
 	# $(GPP) tests/test.cpp -o test -c -O3
 	objdump -W test | less
 	rm test
 test_cpp_ll:
-	$(CLANGPP_EXE) ../test/test.cpp -o test.ll -c -O3 -emit-llvm -S -std=c++11 -g
+	$(CLANGPP_EXE) $(TEST_DIR)/test.cpp -o test.ll -c -O3 -emit-llvm -S -std=c++11 -g
 	less test.ll
 	rm test.ll
 
 TEST_EXT_MODULE_NAMES := basic_test descr_test
 
 .PHONY: ext_pyston
-ext_pyston: $(TEST_EXT_MODULE_NAMES:%=../test/test_extension/%.pyston.so)
-../test/test_extension/%.pyston.so: ../test/test_extension/%.o $(BUILD_SYSTEM_DEPS)
+ext_pyston: $(TEST_EXT_MODULE_NAMES:%=$(TEST_DIR)/test_extension/%.pyston.so)
+$(TEST_DIR)/test_extension/%.pyston.so: $(TEST_DIR)/test_extension/%.o $(BUILD_SYSTEM_DEPS)
 	$(CLANG_EXE) -shared $< -o $@ -g
-../test/test_extension/%.o: ../test/test_extension/%.c $(wildcard ../include/*.h) $(BUILD_SYSTEM_DEPS)
-	$(CLANG_EXE) -O2 -fPIC -Wimplicit -I../include -c $< -o $@ -g
+$(TEST_DIR)/test_extension/%.o: $(TEST_DIR)/test_extension/%.c $(wildcard ./include/*.h) $(BUILD_SYSTEM_DEPS)
+	$(CLANG_EXE) -O2 -fPIC -Wimplicit -I./include -c $< -o $@ -g
 
 .PHONY: ext_python
-ext_python: $(TEST_EXT_MODULE_NAMES:%=../test/test_extension/*.c)
-	cd ../test/test_extension; python setup.py build
+ext_python: $(TEST_EXT_MODULE_NAMES:%=$(TEST_DIR)/test_extension/*.c)
+	cd $(TEST_DIR)/test_extension; python setup.py build
 
 $(FROM_CPYTHON_SRCS:.c=.o): %.o: %.c $(BUILD_SYSTEM_DEPS)
 	$(ECHO) Compiling C file to $@

cmake/FindValgrind.cmake

+# find valgrind header and binary
+include(FindPackageHandleStandardArgs)
+
+find_path(VALGRIND_INCLUDE_DIR
+          NAMES valgrind.h
+          PATHS /usr/include /usr/include/valgrind ${VALGRIND_DIR}/include)
+
+find_program(VALGRIND_BIN NAMES valgrind PATH /usr/bin ${VALGRIND_DIR}/bin)
+
+find_package_handle_standard_args(valgrind REQUIRED_VARS VALGRIND_BIN VALGRIND_INCLUDE_DIR)

lib_python/CMakeLists.txt

+# compile specified files in lib_python/2.7_Modules
+file(GLOB_RECURSE FROM_CPYTHON_SRCS errnomodule.c shamodule.c sha256module.c sha512module.c _math.c mathmodule.c md5.c md5module.c _randommodule.c _sre.c operator.c binascii.c)
+set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-missing-field-initializers")
+add_library(FROM_CPYTHON_OBJECTS OBJECT ${FROM_CPYTHON_SRCS})

libpypa @ 1245304c

+Subproject commit 1245304cce0e4f58e9ec311add5f70ef54929ea3

libunwind @ c90a2e02

+Subproject commit c90a2e02b3c1b03362a549a05261a4d0513d6026

src/CMakeLists.txt

+set(CMAKE_INCLUDE_CURRENT_DIR ON)
+set(CMAKE_CXX_FLAGS_DEBUG "-g -DBINARY_SUFFIX= -DBINARY_STRIPPED_SUFFIX=_stripped")
+set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -fstrict-aliasing -enable-tbaa -DNVALGRIND -DBINARY_SUFFIX=_release -DBINARY_STRIPPED_SUFFIX=")
+
+execute_process(COMMAND git rev-parse HEAD WORKING_DIRECTORY ${CMAKE_SOURCE_DIR} OUTPUT_VARIABLE GITREV OUTPUT_STRIP_TRAILING_WHITESPACE)
+set_source_files_properties(jit.cpp PROPERTIES COMPILE_DEFINITIONS "GITREV=${GITREV}")
+
+include_directories(${CMAKE_BINARY_DIR})
+include_directories(${CMAKE_BINARY_DIR}/libunwind/include)
+include_directories(${CMAKE_SOURCE_DIR}/libpypa/src)
+
+file(GLOB ANALYSIS_SRCS analysis/*.cpp)
+file(GLOB ASM_WRITING_SRCS asm_writing/*.cpp)
+file(GLOB CAPI_SRCS capi/*.c capi/*.cpp)
+file(GLOB CODEGEN_IRGEN_SRCS codegen/irgen/*.cpp)
+file(GLOB CODEGEN_OPT_SRCS codegen/opt/*.cpp)
+file(GLOB CODEGEN_SRCS codegen/*.cpp)
+file(GLOB CORE_SRCS core/*.cpp)
+file(GLOB GC_SRCS gc/*.cpp)
+file(GLOB RUNTIME_BUILTIN_MODULES_SRCS runtime/builtin_modules/*.cpp)
+file(GLOB RUNTIME_SRCS runtime/*.cpp)
+
+add_library(PYSTON_OBJECTS OBJECT codegen/profiling/profiling.cpp ${ANALYSIS_SRCS} ${ASM_WRITING_SRCS} ${CAPI_SRCS} ${CODEGEN_SRCS} ${CODEGEN_IRGEN_SRCS} ${CODEGEN_OPT_SRCS} ${CORE_SRCS} ${GC_SRCS} ${RUNTIME_BUILTIN_MODULES_SRCS} ${RUNTIME_SRCS})
+add_dependencies(PYSTON_OBJECTS libunwind pypa ${LLVM_LIBS})
+add_library(PYSTON_MAIN_OBJECT OBJECT jit.cpp)
+add_dependencies(PYSTON_MAIN_OBJECT ${LLVM_LIBS})
+
+# build stdlib
+add_subdirectory(runtime/inline)
+
+add_custom_target(cpplint python ${CMAKE_SOURCE_DIR}/tools/cpplint.py --filter=-whitespace,-build/header_guard,-build/include_order,-readability/todo ${ANALYSIS_SRCS} ${ASM_WRITING_SRCS} ${CAPI_SRCS} ${CODEGEN_SRCS} ${CODEGEN_IRGEN_SRCS} ${CODEGEN_OPT_SRCS} ${CORE_SRCS} ${GC_SRCS} ${RUNTIME_SRCS} ${RUNTIME_BUILTIN_MODULES_SRCS} ${FROM_CPYTHON_SRCS} WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src)

src/codegen/parser.cpp

@@ -889,9 +889,6 @@ static std::string getParserCommandLine(const char* fn) {
     // Start by removing the binary name, because the "pyston" binary will break the logic below
     llvm::sys::path::remove_filename(parse_ast_fn);
 
-    while (llvm::sys::path::filename(parse_ast_fn) != "pyston") {
-        llvm::sys::path::remove_filename(parse_ast_fn);
-    }
     llvm::sys::path::append(parse_ast_fn, "src/codegen/parse_ast.py");
 
     return std::string("python -S ") + parse_ast_fn.str().str() + " " + fn;

src/jit.cpp

@@ -119,7 +119,6 @@ int main(int argc, char** argv) {
 
     llvm::SmallString<128> stdlib_dir(self_path);
     llvm::sys::path::remove_filename(stdlib_dir); // executable name
-    llvm::sys::path::remove_filename(stdlib_dir); // "src/" dir
     llvm::sys::path::append(stdlib_dir, "lib_python");
     llvm::sys::path::append(stdlib_dir, "2.7");
     appendToSysPath(stdlib_dir.c_str());

src/runtime/capi.cpp

@@ -937,7 +937,7 @@ extern "C" Py_ssize_t PyNumber_AsSsize_t(PyObject* o, PyObject* exc) {
 }
 
 BoxedModule* importTestExtension(const std::string& name) {
-    std::string pathname_name = "../test/test_extension/" + name + ".pyston.so";
+    std::string pathname_name = "test/test_extension/" + name + ".pyston.so";
     const char* pathname = pathname_name.c_str();
     void* handle = dlopen(pathname, RTLD_NOW);
     if (!handle) {

src/runtime/inline/CMakeLists.txt

+# Copyright (c) 2010-2011, Rob Jansen
+# 
+# To the extent that a federal employee is an author of a portion of
+# this software or a derivative work thereof, no copyright is claimed by
+# the United States Government, as represented by the Secretary of the
+# Navy ("GOVERNMENT") under Title 17, U.S. Code. All Other Rights 
+# Reserved.
+# 
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions are
+# met:
+#     * Redistributions of source code must retain the above copyright
+# notice, this list of conditions and the following disclaimer.
+#     * Redistributions in binary form must reproduce the above
+# copyright notice, this list of conditions and the following disclaimer
+# in the documentation and/or other materials provided with the
+# distribution.
+#     * Neither the names of the copyright owners nor the names of its
+# contributors may be used to endorse or promote products derived from
+# this software without specific prior written permission.
+# 
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+# GOVERNMENT ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS" CONDITION
+# AND DISCLAIMS ANY LIABILITY OF ANY KIND FOR ANY DAMAGES WHATSOEVER
+# RESULTING FROM THE USE OF THIS SOFTWARE.
+
+# adapted from https://github.com/shadow/shadow/blob/master/cmake/LLVMTools.cmake
+
+set(BC_INLINE_SRCS boxing.cpp dict.cpp link_forcer.cpp list.cpp tuple.cpp xrange.cpp)
+include_directories(${CMAKE_SOURCE_DIR}/src)
+
+# set CXX flags
+set(BC_CXX_FLAGS "")
+if(${CMAKE_BUILD_TYPE} STREQUAL "Debug")
+  separate_arguments(BC_CXX_FLAGS UNIX_COMMAND "${CMAKE_CXX_FLAGS} ${CLANG_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG}")
+else()
+  separate_arguments(BC_CXX_FLAGS UNIX_COMMAND "${CMAKE_CXX_FLAGS} ${CLANG_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE}")
+  set(OPT_OPTIONS "-strip-debug")
+  set(STDLIB_SUFFIX ".release")
+endif()
+
+# set defines
+set(BC_DEFINES "")
+get_directory_property(COMPILE_DEFINITIONS COMPILE_DEFINITIONS)
+foreach(DEFINITION ${COMPILE_DEFINITIONS})
+  list(APPEND BC_DEFINES -D${DEFINITION})
+endforeach(DEFINITION)
+
+# set includes
+set(BC_INCLUDES "")
+get_directory_property(INCLUDE_DIRECTORIES INCLUDE_DIRECTORIES)
+foreach(DIRECTORY ${INCLUDE_DIRECTORIES})
+  list(APPEND BC_INCLUDES -I${DIRECTORY})
+endforeach(DIRECTORY)
+
+set(BC_FILES "")
+set(BC_OBJS "")
+foreach(BC_SRC ${BC_INLINE_SRCS})
+  get_filename_component(BC_SRC_BASENAME ${BC_SRC} NAME)
+  get_filename_component(BC_SRC_FULLPATH ${BC_SRC} ABSOLUTE)
+
+  # generate the bitcode for this file
+  add_custom_command(OUTPUT ${BC_SRC_BASENAME}.bc
+                     COMMAND ${LLVM_TOOLS_BINARY_DIR}/clang++ ${BC_DEFINES} ${BC_CXX_FLAGS} ${BC_INCLUDES} -c ${BC_SRC_FULLPATH} -o ${BC_SRC_BASENAME}.bc -emit-llvm
+                     DEPENDS ${BC_SRC_FULLPATH} clang
+                     COMMENT "Building LLVM bitcode ${BC_SRC_BASENAME}.bc"
+                     VERBATIM)
+  set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${BC_SRC_BASENAME}.bc)
+
+  # publicize the bitcode file
+  add_custom_command(OUTPUT ${BC_SRC_BASENAME}.pub.bc
+                     COMMAND ${CMAKE_BINARY_DIR}/tools/publicize ${BC_SRC_BASENAME}.bc -o ${BC_SRC_BASENAME}.pub.bc
+                     DEPENDS ${BC_SRC_BASENAME}.bc publicize
+                     COMMENT "Publicizing LLVM bitcode ${BC_SRC_BASENAME}.pub.bc"
+                     VERBATIM)
+  set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${BC_SRC_BASENAME}.pub.bc)
+  set_source_files_properties(${BC_SRC_BASENAME}.pub.bc PROPERTIES LANGUAGE CXX)
+
+  # compile into a regular object file
+  add_custom_command(OUTPUT ${BC_SRC_BASENAME}.o
+                     COMMAND ${LLVM_TOOLS_BINARY_DIR}/clang++ ${BC_DEFINES} ${BC_CXX_FLAGS} ${BC_INCLUDES} -c ${BC_SRC_BASENAME}.pub.bc -o ${BC_SRC_BASENAME}.o
+                     DEPENDS ${BC_SRC_BASENAME}.pub.bc clang
+                     COMMENT "Compiling ${BC_SRC_BASENAME}.pub.bc -> ${BC_SRC_BASENAME}.o"
+                     VERBATIM)
+  set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${BC_SRC_BASENAME}.o)
+  set_source_files_properties(${BC_SRC_BASENAME}.o PROPERTIES EXTERNAL_OBJECT true GENERATED true)
+
+  # keep track of every bitcode and object file we created
+  list(APPEND BC_FILES ${BC_SRC_BASENAME}.pub.bc)
+  list(APPEND BC_OBJS ${BC_SRC_BASENAME}.o)
+endforeach(BC_SRC)
+
+# link all the bitcode files together
+add_custom_command(OUTPUT stdlib.unopt.bc
+                   COMMAND ${LLVM_TOOLS_BINARY_DIR}/llvm-link -o ${CMAKE_CURRENT_BINARY_DIR}/stdlib.unopt.bc ${BC_FILES}
+                   DEPENDS ${BC_FILES} llvm-link
+                   COMMENT "Linking stdlib.unopt.bc")
+
+# optimize stdlib
+add_custom_command(OUTPUT stdlib${STDLIB_SUFFIX}.bc
+                   COMMAND ${LLVM_TOOLS_BINARY_DIR}/opt -O3 ${OPT_OPTIONS} stdlib.unopt.bc -o stdlib${STDLIB_SUFFIX}.bc
+                   DEPENDS stdlib.unopt.bc opt
+                   COMMENT "Optimizing stdlib.unopt.bc -> stdlib.bc")
+
+add_custom_command(OUTPUT stdlib.bc.o
+                   COMMAND ${CMAKE_LINKER} -r -b binary stdlib${STDLIB_SUFFIX}.bc -o ${CMAKE_CURRENT_BINARY_DIR}/stdlib.bc.o
+                   DEPENDS stdlib${STDLIB_SUFFIX}.bc
+                   COMMENT "Embedding stdlib${STDLIB_SUFFIX}.bc -> stdlib.bc.o")
+
+if(${CMAKE_BUILD_TYPE} STREQUAL "Debug")
+  add_custom_command(OUTPUT stdlib.stripped.bc
+                     COMMAND ${LLVM_TOOLS_BINARY_DIR}/opt -strip-debug stdlib.bc -o ${CMAKE_CURRENT_BINARY_DIR}/stdlib.stripped.bc
+                     DEPENDS stdlib.bc opt
+                     COMMENT "Stripping stdlib.bc -> stdlib.stripped.bc")
+
+  add_custom_command(OUTPUT stdlib.stripped.bc.o
+                     COMMAND ${CMAKE_LINKER} -r -b binary stdlib.stripped.bc -o ${CMAKE_CURRENT_BINARY_DIR}/stdlib.stripped.bc.o
+                     DEPENDS stdlib.stripped.bc
+                     COMMENT "Embedding stdlib.stripped.bc -> stdlib.stripped.bc.o")
+  add_library(stdlib stdlib.stripped.bc.o stdlib.bc.o ${BC_OBJS})
+else()
+  add_library(stdlib stdlib.bc.o ${BC_OBJS})
+endif()
+set_property(TARGET stdlib PROPERTY LINKER_LANGUAGE C)
+set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "stdlib.unopt.bc;stdlib.bc;stdlib.bc.o;stdlib.stripped.bc;stdlib.stripped.bc.o;stdlib.release.bc")
+

test/test_extension/CMakeLists.txt

+set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-missing-field-initializers")
+set(CMAKE_SHARED_LIBRARY_PREFIX "")
+set(CMAKE_SHARED_LIBRARY_SUFFIX ".pyston${CMAKE_SHARED_LIBRARY_SUFFIX}")
+
+add_custom_command(OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/build/lib.linux-x86_64-2.7/basic_test.so
+                   COMMAND python setup.py build
+                   DEPENDS basic_test.c descr_test.c
+                   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
+
+add_library(basic_test SHARED basic_test.c)
+add_library(descr_test SHARED descr_test.c)
+
+add_custom_target(ext_cpython DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/build/lib.linux-x86_64-2.7/basic_test.so)
+add_custom_target(ext_pyston DEPENDS basic_test descr_test)

test/unittests/CMakeLists.txt

+set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-undef")
+set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
+
+add_definitions(-DGTEST_HAS_RTTI=0 ${LLVM_DEFINITIONS})
+include_directories(${CMAKE_SOURCE_DIR}/src)
+include_directories(${LLVM_SOURCE_DIR}/utils/unittest/googletest/include)
+
+add_custom_target(unittests)
+
+macro(add_unittest unittest)
+  add_executable(${unittest}_unittest EXCLUDE_FROM_ALL ${unittest}.cpp $<TARGET_OBJECTS:PYSTON_OBJECTS> $<TARGET_OBJECTS:FROM_CPYTHON_OBJECTS>)
+  target_link_libraries(${unittest}_unittest stdlib gmp readline pypa double-conversion unwind gtest gtest_main ${LLVM_LIBS} ${LIBLZMA_LIBRARIES})
+  add_dependencies(${unittest}_unittest gtest gtest_main)
+  add_dependencies(unittests ${unittest}_unittest)
+endmacro()
+
+add_unittest(gc)
+add_unittest(analysis)
+add_custom_command(TARGET analysis_unittest POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_SOURCE_DIR}/test/unittests/analysis_listcomp.py ${CMAKE_BINARY_DIR}/test/unittests/analysis_listcomp.py)

test/unittests/analysis.cpp

@@ -22,7 +22,7 @@ protected:
 };
 
 TEST_F(AnalysisTest, augassign) {
-    const std::string fn("../test/unittests/analysis_listcomp.py");
+    const std::string fn("test/unittests/analysis_listcomp.py");
     AST_Module* module = caching_parse(fn.c_str());
     assert(module);
 

tools/CMakeLists.txt

+add_executable(demangle EXCLUDE_FROM_ALL demangle.cpp)
+add_executable(mcjitcache EXCLUDE_FROM_ALL mcjitcache.cpp)
+
+llvm_map_components_to_libnames(LLVM_LIBS_EXTRA BitWriter)
+
+add_executable(publicize publicize.cpp)
+target_link_libraries(publicize curses dl pthread ${LLVM_LIBS} ${LLVM_LIBS_EXTRA}) 
+add_dependencies(publicize ${LLVM_LIBS_EXTRA})
+
+include_directories(${CMAKE_SOURCE_DIR}/src)
+add_executable(astprint EXCLUDE_FROM_ALL astprint.cpp $<TARGET_OBJECTS:PYSTON_OBJECTS> $<TARGET_OBJECTS:FROM_CPYTHON_OBJECTS>)
+target_link_libraries(astprint stdlib gmp readline pypa double-conversion unwind ${LLVM_LIBS} ${LIBLZMA_LIBRARIES})
+  

tools/tester.py

@@ -69,7 +69,7 @@ def get_expected_output(fn):
 
     # TODO don't suppress warnings globally:
     env = dict(os.environ)
-    env["PYTHONPATH"] = "../test/test_extension/build/lib.linux-x86_64-2.7/"
+    env["PYTHONPATH"] = os.path.dirname(os.path.realpath(__file__)) + "/../test/test_extension/build/lib.linux-x86_64-2.7/"
     p = subprocess.Popen(["python", "-Wignore", fn], stdout=subprocess.PIPE, stderr=subprocess.PIPE, stdin=open("/dev/null"), preexec_fn=set_ulimits, env=env)
     out, err = p.communicate()
     code = p.wait()