base project for qmake.

Common/base.pri

+# CONFIGURATION
+CONFIG(debug, debug|release) {
+    CONFIG += core_debug
+} else {
+    CONFIG += core_release
+}
+
+#PLATFORM
+win32 {
+    CONFIG += core_windows
+}
+
+win32:contains(QMAKE_TARGET.arch, x86_64): {
+    CONFIG += core_win_64
+}
+win32:!contains(QMAKE_TARGET.arch, x86_64): {
+    CONFIG += core_win_32
+}
+
+linux-g++ | linux-g++-64 | linux-g++-32 {
+    CONFIG += core_linux
+}
+linux-g++:contains(QMAKE_HOST.arch, x86_64): {
+    CONFIG += core_linux_64
+}
+linux-g++:!contains(QMAKE_HOST.arch, x86_64): {
+    CONFIG += core_linux_32
+}
+
+mac {
+    CONFIG += core_mac
+    CONFIG += core_mac_64
+}
+
+# DEFINES
+core_windows {
+    DEFINES += WIN32 _WIN32
+}
+core_win_64 {
+    DEFINES += WIN64 _WIN64
+}
+
+core_linux {
+    DEFINES += LINUX _LINUX
+}
+
+core_mac {
+    DEFINES += LINUX _LINUX MAC _MAC
+}
+
+# PREFIXES
+core_windows {
+    CONFIG -= debug_and_release debug_and_release_target
+    QMAKE_CXXFLAGS_RELEASE -= -Zc:strictStrings
+}
+
+core_win_32 {
+    CORE_BUILDS_PLATFORM_PREFIX = win_32
+}
+core_win_64 {
+    CORE_BUILDS_PLATFORM_PREFIX = win_64
+}
+core_linux_32 {
+    CORE_BUILDS_PLATFORM_PREFIX = linux_32
+}
+core_linux_64 {
+    CORE_BUILDS_PLATFORM_PREFIX = linux_64
+}
+core_mac_64 {
+    CORE_BUILDS_PLATFORM_PREFIX = mac_64
+}
+
+core_debug {
+    CORE_BUILDS_CONFIGURATION_PREFIX    = debug
+}
+core_release {
+    CORE_BUILDS_CONFIGURATION_PREFIX    = release
+}
+
+# MESSAGE
+message($$CORE_BUILDS_PLATFORM_PREFIX/$$CORE_BUILDS_CONFIGURATION_PREFIX)
+
+# COMPILER
+CONFIG += c++11
+
+core_linux {
+core_static_link_libstd {
+    QMAKE_LFLAGS += -static-libstdc++ -static-libgcc
+    message(core_static_link_libstd)
+}
+plugin {
+    QMAKE_CXXFLAGS += -fvisibility=hidden
+    QMAKE_CFLAGS += -fvisibility=hidden
+
+    TARGET_EXT = .so
+}
+}
+
+core_mac {
+plugin {
+    QMAKE_CXXFLAGS += -fvisibility=hidden
+    QMAKE_CFLAGS += -fvisibility=hidden
+}
+}
+
+core_windows {
+plugin {
+    TARGET_EXT = .dll
+}
+}
+
+# BUILD_PATHS
+# MUST BE DEFINED CORE_ROOT_DIR
+DESTDIR     = $$PWD_ROOT_DIR/core_build/$$CORE_BUILDS_PLATFORM_PREFIX/$$CORE_BUILDS_CONFIGURATION_PREFIX
+OBJECTS_DIR = $$PWD_ROOT_DIR/core_build/$$CORE_BUILDS_PLATFORM_PREFIX/$$CORE_BUILDS_CONFIGURATION_PREFIX/obj
+MOC_DIR     = $$PWD_ROOT_DIR/core_build/$$CORE_BUILDS_PLATFORM_PREFIX/$$CORE_BUILDS_CONFIGURATION_PREFIX/moc
+RCC_DIR     = $$PWD_ROOT_DIR/core_build/$$CORE_BUILDS_PLATFORM_PREFIX/$$CORE_BUILDS_CONFIGURATION_PREFIX/rcc
+UI_DIR      = $$PWD_ROOT_DIR/core_build/$$CORE_BUILDS_PLATFORM_PREFIX/$$CORE_BUILDS_CONFIGURATION_PREFIX/ui
+
+CORE_BUILDS_LIBRARIES_PATH = $$CORE_ROOT_DIR/build/lib/$$CORE_BUILDS_PLATFORM_PREFIX
+core_windows {
+core_debug {
+    CORE_BUILDS_LIBRARIES_PATH = $$CORE_BUILDS_LIBRARIES_PATH/DEBUG
+}
+}
+
+plugin {
+    DESTDIR = $$CORE_BUILDS_LIBRARIES_PATH
+}

DesktopEditor/Qt_build/graphics/project/graphics_fonts.pri

-CONFIG += c++11
-
+DESKTOPEDITOR_PATH =  $$CORE_ROOT_DIR/DesktopEditor
 DEFINES += \
     _QT \
     FT2_BUILD_LIBRARY
 
-linux-g++ | linux-g++-64 | linux-g++-32 {
+core_linux {
     DEFINES += \
-    HAVE_UNISTD_H \
-    LINUX \
-    _LINUX \
-    _LINUX_QT
+    HAVE_UNISTD_H
 }
 
-mac {
+core_mac {
     DEFINES += \
-    HAVE_UNISTD_H \
-    _LINUX \
-    _LINUX_QT \
-    _MAC \
-    QT_MAC
-}
-
-win32 {
-    DEFINES += \
-    WIN32
-
-    QMAKE_CXXFLAGS_RELEASE -= -Zc:strictStrings
+    HAVE_UNISTD_H
 }
 
 INCLUDEPATH += \

DesktopEditor/doctrenderer/doctrenderer.pro

@@ -16,165 +16,19 @@ CONFIG += plugin
 
 CONFIG += c++11
 
-############### destination path ###############
-DESTINATION_SDK_PATH = $$PWD/../../build/lib
+CONFIG += core_static_link_libstd
 
-# WINDOWS
-win32:contains(QMAKE_TARGET.arch, x86_64):{
-CONFIG(debug, debug|release) {
-    DESTDIR = $$DESTINATION_SDK_PATH/win_64/DEBUG
-} else {
-    DESTDIR = $$DESTINATION_SDK_PATH/win_64
-}
-}
-win32:!contains(QMAKE_TARGET.arch, x86_64):{
-CONFIG(debug, debug|release) {
-    DESTDIR = $$DESTINATION_SDK_PATH/win_32/DEBUG
-} else {
-    DESTDIR = $$DESTINATION_SDK_PATH/win_32
-}
-}
-
-linux-g++:contains(QMAKE_HOST.arch, x86_64):{
-    DESTDIR = $$DESTINATION_SDK_PATH/linux_64
-}
-linux-g++:!contains(QMAKE_HOST.arch, x86_64):{
-    DESTDIR = $$DESTINATION_SDK_PATH/linux_32
-}
-
-mac {
-    DESTDIR = $$DESTINATION_SDK_PATH/mac_64
-}
-
-################################################
-
-LIBS_DESTDIR_PATH = $$DESTDIR
-# теперь всегда с libstd
-linux-g++ | linux-g++-64 | linux-g++-32 {
-    CONFIG += static_link_libstd
-}
-static_link_libstd {
-    QMAKE_LFLAGS += -static-libstdc++ -static-libgcc
-#    DESTDIR_POSTFIX = _static_stdlib
-#    DESTDIR = $$DESTDIR$$DESTDIR_POSTFIX
-    message(static_link_libstd)
-}
-
-win32 {
-    V8_CHECKOUT_PATH = D:/GIT/v8/v8
-}
-
-linux-g++ | linux-g++-64 | linux-g++-32 {
-    V8_CHECKOUT_PATH = ../../../../v8
-}
-
-mac {
-    V8_CHECKOUT_PATH = /Users/Oleg/Desktop/GIT/v8_mac/v8
-}
-
-win32 {
-    LIBS += -lwinmm
-    LIBS += -ladvapi32
-    LIBS += -lShell32
-
-    TARGET_EXT = .dll
-}
-
-linux-g++ | linux-g++-64 | linux-g++-32 {
-    CONFIG += plugin
-
-    QMAKE_CXXFLAGS += -fvisibility=hidden
-    QMAKE_CFLAGS += -fvisibility=hidden
-
-    TARGET_EXT = .so
-}
+CORE_ROOT_DIR = $$PWD/../..
+PWD_ROOT_DIR = $$PWD
+include(../../Common/base.pri)
 
-mac {
-    CONFIG += plugin
-
-    QMAKE_CXXFLAGS += -fvisibility=hidden -Wall -Wno-inconsistent-missing-override
-    QMAKE_CFLAGS += -fvisibility=hidden -Wall -Wno-inconsistent-missing-override
-}
-
-INCLUDEPATH += \
-    $$V8_CHECKOUT_PATH \
-    $$V8_CHECKOUT_PATH/include
-
-DEFINES += NEW_V8_ENGINE
-
-#################### WINDOWS #####################
-DESKTOPEDITOR_PATH = ..
 include(../Qt_build/graphics/project/graphics_fonts.pri)
-
-LIB_XML_PRI_PATH = ../xml
 include(../xml/build/qt/libxml2.pri)
 
 CONFIG += build_all_zlib build_zlib_as_sources
 include(../../OfficeUtils/OfficeUtils.pri)
 
-win32:contains(QMAKE_TARGET.arch, x86_64):{
-
-CONFIG(debug, debug|release) {
-    LIBS += -L$$V8_CHECKOUT_PATH/build/Debug/lib -lv8_base_0 -lv8_base_1 -lv8_base_2 -lv8_base_3 -lv8_libbase -lv8_libplatform -lv8_nosnapshot -lv8_external_snapshot
-    LIBS += -L$$V8_CHECKOUT_PATH/build/Debug/lib -licui18n -licuuc
-} else {
-    LIBS += -L$$V8_CHECKOUT_PATH/build/Release/lib -lv8_base_0 -lv8_base_1 -lv8_base_2 -lv8_base_3 -lv8_libbase -lv8_libplatform -lv8_nosnapshot -lv8_external_snapshot
-    LIBS += -L$$V8_CHECKOUT_PATH/build/Release/lib -licui18n -licuuc
-}
-
-    message(windows64)
-}
-win32:!contains(QMAKE_TARGET.arch, x86_64):{
-
-CONFIG(debug, debug|release) {
-    LIBS += -L$$V8_CHECKOUT_PATH/build/Debug/lib -lv8_base_0 -lv8_base_1 -lv8_base_2 -lv8_base_3 -lv8_libbase -lv8_libplatform -lv8_nosnapshot -lv8_external_snapshot
-    LIBS += -L$$V8_CHECKOUT_PATH/build/Debug/lib -licui18n -licuuc
-} else {
-    LIBS += -L$$V8_CHECKOUT_PATH/build/Release/lib -lv8_base_0 -lv8_base_1 -lv8_base_2 -lv8_base_3 -lv8_libbase -lv8_libplatform -lv8_nosnapshot -lv8_external_snapshot
-    LIBS += -L$$V8_CHECKOUT_PATH/build/Release/lib -licui18n -licuuc
-}
-
-    message(windows32)
-}
-##################################################
-
-################### LINUX ########################
-
-linux-g++ | linux-g++-64 | linux-g++-32 {
-    DEFINES += \
-        LINUX \
-        _LINUX \
-        _LINUX_QT \
-
-    LIBS += -L$$V8_CHECKOUT_PATH/out/native/obj.target/tools/gyp -lv8_base -lv8_libplatform -lv8_libbase -lv8_nosnapshot -lv8_external_snapshot
-    LIBS += -L$$V8_CHECKOUT_PATH/out/native/obj.target/third_party/icu -licui18n -licuuc -licudata
-}
-
-linux-g++:contains(QMAKE_HOST.arch, x86_64):{
-    message(linux64)
-}
-linux-g++:!contains(QMAKE_HOST.arch, x86_64):{
-    message(linux32)
-}
-
-##################################################
-
-#################### MAC #########################
-mac {
-    DEFINES += \
-    LINUX \
-    _LINUX \
-    _LINUX_QT \
-    _MAC \
-    MAC \
-    QT_MAC
-
-    LIBS += -L$$V8_CHECKOUT_PATH/out/native -lv8_base -lv8_libbase -lv8_libplatform -lv8_nosnapshot -lv8_external_snapshot
-    LIBS += -L$$V8_CHECKOUT_PATH/out/native -licui18n -licuuc -licudata
-
-    message(mac)
-}
-##################################################
+include(../../Common/3dParty/v8/v8.pri)
 
 SOURCES += \
     memorystream.cpp \

DesktopEditor/xml/build/qt/libxml2.pri

 DEFINES += HAVE_VA_COPY
 
 INCLUDEPATH += \
-    $$LIB_XML_PRI_PATH/libxml2/include \
-    $$LIB_XML_PRI_PATH/libxml2/include/libxml \
-    $$LIB_XML_PRI_PATH/build/qt
+    $$CORE_ROOT_DIR/DesktopEditor/xml/libxml2/include \
+    $$CORE_ROOT_DIR/DesktopEditor/xml/libxml2/include/libxml \
+    $$CORE_ROOT_DIR/DesktopEditor/xml/build/qt
 
-SOURCES += $$LIB_XML_PRI_PATH/build/qt/libxml2_all.c
-SOURCES += $$LIB_XML_PRI_PATH/build/qt/libxml2_all2.c
-#SOURCES +=  \
-#    $$LIB_XML_PRI_PATH/libxml2/buf.c \
-#    $$LIB_XML_PRI_PATH/libxml2/c14n.c \
-#    $$LIB_XML_PRI_PATH/libxml2/catalog.c \
-#    $$LIB_XML_PRI_PATH/libxml2/chvalid.c \
-#    $$LIB_XML_PRI_PATH/libxml2/debugXML.c \
-#    $$LIB_XML_PRI_PATH/libxml2/dict.c \
-#    $$LIB_XML_PRI_PATH/libxml2/DOCBparser.c \
-#    $$LIB_XML_PRI_PATH/libxml2/encoding.c \
-#    $$LIB_XML_PRI_PATH/libxml2/entities.c \
-#    $$LIB_XML_PRI_PATH/libxml2/error.c \
-#    $$LIB_XML_PRI_PATH/libxml2/globals.c \
-#    $$LIB_XML_PRI_PATH/libxml2/HTMLparser.c \
-#    $$LIB_XML_PRI_PATH/libxml2/HTMLtree.c \
-#    $$LIB_XML_PRI_PATH/libxml2/legacy.c \
-#    $$LIB_XML_PRI_PATH/libxml2/list.c \
-#    $$LIB_XML_PRI_PATH/libxml2/nanoftp.c \
-#    $$LIB_XML_PRI_PATH/libxml2/nanohttp.c \
-#    $$LIB_XML_PRI_PATH/libxml2/parser.c \
-#    $$LIB_XML_PRI_PATH/libxml2/pattern.c \
-#    $$LIB_XML_PRI_PATH/libxml2/relaxng.c \
-#    $$LIB_XML_PRI_PATH/libxml2/SAX.c \
-#    $$LIB_XML_PRI_PATH/libxml2/SAX2.c \
-#    $$LIB_XML_PRI_PATH/libxml2/schematron.c \
-#    $$LIB_XML_PRI_PATH/libxml2/threads.c \
-#    $$LIB_XML_PRI_PATH/libxml2/tree.c \
-#    $$LIB_XML_PRI_PATH/libxml2/uri.c \
-#    $$LIB_XML_PRI_PATH/libxml2/valid.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xinclude.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xlink.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlIO.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlmemory.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlmodule.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlreader.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlregexp.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlsave.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlschemas.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlschemastypes.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlstring.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlunicode.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xmlwriter.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xpath.c \
-#    $$LIB_XML_PRI_PATH/libxml2/xpointer.c \
-#    $$LIB_XML_PRI_PATH/libxml2/parserInternals.c \
-#    $$LIB_XML_PRI_PATH/libxml2/hash.c
+SOURCES += $$CORE_ROOT_DIR/DesktopEditor/xml/build/qt/libxml2_all.c
+SOURCES += $$CORE_ROOT_DIR/DesktopEditor/xml/build/qt/libxml2_all2.c
 
 SOURCES +=  \
-    $$LIB_XML_PRI_PATH/src/xmllight.cpp \
-    $$LIB_XML_PRI_PATH/src/xmldom.cpp
+    $$CORE_ROOT_DIR/DesktopEditor/xml/src/xmllight.cpp \
+    $$CORE_ROOT_DIR/DesktopEditor/xml/src/xmldom.cpp

OfficeUtils/OfficeUtils.pri

-CONFIG += c++11
-win32 {
-    QMAKE_CXXFLAGS_RELEASE -= -Zc:strictStrings
-} else {
+core_linux {
     QMAKE_CXXFLAGS += -Wall -Wno-ignored-qualifiers
 }
-
-SOURCES_UTILS = $$PWD/src
-
-#################### WINDOWS #####################
-win32 {
-DEFINES += WIN32
+core_mac {
+    QMAKE_CXXFLAGS += -Wall -Wno-ignored-qualifiers
+    DEFINES += unix
 }
-#################### WINDOWS #####################
 
-#################### LINUX ########################
-linux-g++ | linux-g++-64 | linux-g++-32 {
-    DEFINES += \
-        LINUX \
-        _LINUX \
-        _LINUX_QT
-}
-mac {
-    DEFINES += \
-        MAC \
-        _MAC \
-        unix
-}
-#################### LINUX ########################
+SOURCES_UTILS = $$CORE_ROOT_DIR/OfficeUtils/src
 
 build_zlib_as_sources {
     DEFINES += BUILD_ZLIB_AS_SOURCES